• Une cohorte regroupe les clients acquis au cours d'une même période (ici, le mois de leur premier achat). L'analyse de cohortes suit chaque groupe dans le temps pour mesurer la fidélisation : sur les clients acquis en janvier, combien reviennent un mois, deux mois, trois mois plus tard ?
• Elle est très utilisée en SaaS, en e-commerce et en marketing pour juger la rétention et l'attrition (churn).

• Cohortes_Depart : le modèle sans les colonnes ni les mesures, avec les consignes. Décompressez le dossier, puis ouvrez le fichier .pbip.
• Jeu de données fictif : 1 105 clients acquis de janvier 2024 à décembre 2025, 4 477 commandes.
• Corrigé : le PBIP Cohortes_Corrige (colonnes calculées, mesures Clients, Rétention %, Cohorte et CA cumulé par client, une page par matrice) est remis par le formateur.

• En lignes : le mois d'acquisition (mois du premier achat).
• En colonnes : le nombre de mois écoulés depuis l'acquisition (0, 1, 2, 3...).
• Dans les cellules : le nombre de clients de la cohorte qui ont acheté ce mois-là, puis le même nombre en pourcentage de la cohorte de départ.

• Ventes (table de faits) : NumCommande, Date, ClientID, Montant.
• Client (dimension) : ClientID, Client, Segment, Pays.
• Calendrier : table de dates marquée (non indispensable à la matrice).
• Relation un-à-plusieurs Client[ClientID] vers Ventes[ClientID].

Premier achat = MIN ( Ventes[Date] )

• Résultat : la même date sur toutes les lignes, la plus petite date de toute la table Ventes. Le contexte de ligne (« je suis sur le client 12 ») ne filtre pas la table Ventes.

Premier achat = EOMONTH ( CALCULATE ( MIN ( Ventes[Date] ) ), 0 )

• CALCULATE déclenche la transition de contexte : la ligne courante devient un filtre Client[ClientID] = 12, propagé à Ventes par la relation. On obtient la première date d'achat de ce client. Voir CALCULATE et transition de contexte.
• EOMONTH ( date, 0 ) ramène cette date au dernier jour de son mois : tous les clients acquis en janvier 2024 partagent la valeur 31/01/2024 et forment une seule ligne de la matrice.
• Mettez la colonne au format mmm aaaa (par exemple « janv. 2024 »).
• Source (Microsoft Learn)

Periode cohorte = DATEDIFF ( RELATED ( Client[Premier achat] ), Ventes[Date], MONTH )

• RELATED va chercher la date du premier achat dans la table Client (l'équivalent d'une RECHERCHEV).
• DATEDIFF ( date la plus ancienne, date la plus récente, MONTH ) compte les changements de mois entre les deux dates : 0 pour un achat le mois de l'acquisition, 1 le mois suivant, etc.
• Contrôle : filtrez la table Ventes sur un client et triez par date ; la colonne vaut 0 sur ses premiers achats puis augmente au fil des mois.
• Source (Microsoft Learn)

Clients = DISTINCTCOUNT ( Ventes[ClientID] )

• Un client apparaît sur plusieurs lignes de Ventes : il faut compter les identifiants distincts, pas les lignes.
• Source (Microsoft Learn)

• Lignes : Client[Premier achat].
• Colonnes : Ventes[Periode cohorte].
• Valeurs : [Clients].

Rétention % =
VAR depart =
    CALCULATE ( [Clients], Ventes[Periode cohorte] = 0 )
RETURN
    DIVIDE ( [Clients], depart )

• Dans une cellule (cohorte janvier 2024, période 3), CALCULATE remplace le filtre de la colonne (période 3) par la période 0, mais garde celui de la ligne (janvier 2024) : depart vaut 70.
• DIVIDE renvoie 23 / 70 = 33 %. Mettez la mesure au format pourcentage sans décimale.
• Ajoutez une Mise en forme conditionnelle (couleur d'arrière-plan en dégradé) pour obtenir une carte de chaleur.
• Source (Microsoft Learn)

Rétention % (texte) =
VAR depart =
    CALCULATE ( [Clients], Ventes[Periode cohorte] = 0 )
RETURN
    IF (
        SELECTEDVALUE ( Ventes[Periode cohorte] ) = 0,
        [Clients],
        FORMAT ( DIVIDE ( [Clients], depart ), "0%" )
    )

• Inconvénient : FORMAT renvoie du texte. La mesure ne se prête plus à la mise en forme conditionnelle, ni aux graphiques, ni aux calculs.

Cohorte =
VAR depart =
    CALCULATE ( [Clients], Ventes[Periode cohorte] = 0 )
RETURN
    IF (
        SELECTEDVALUE ( Ventes[Periode cohorte] ) = 0,
        [Clients],
        DIVIDE ( [Clients], depart )
    )

IF ( SELECTEDVALUE ( Ventes[Periode cohorte] ) = 0, "0", "0 %" )

• Source (Microsoft Learn)

CA cumulé par client =
VAR depart =
    CALCULATE ( [Clients], Ventes[Periode cohorte] = 0 )
RETURN
    DIVIDE (
        CALCULATE ( [CA], Ventes[Periode cohorte] <= MAX ( Ventes[Periode cohorte] ) ),
        depart
    )

• MAX ( Ventes[Periode cohorte] ) est évalué dans le contexte de la cellule (par exemple 5), avant que CALCULATE ne remplace le filtre par « période de 0 à 5 ».
• Lecture : « en moyenne, un client acquis en janvier 2024 a rapporté tant d'euros au cours de ses 6 premiers mois ».
• Le taux d'attrition d'une période se déduit de la rétention : 1 - [Rétention %].

• Oublier CALCULATE dans la colonne Premier achat : toutes les lignes affichent la même date.
• Inverser les dates de DATEDIFF : on obtient des périodes négatives. La date la plus ancienne vient en premier.
• Compter les lignes (COUNTROWS ( Ventes )) au lieu des clients distincts : un client qui commande deux fois dans le mois est compté deux fois.
• Hiérarchie de dates automatique : si l'option Date/heure automatique est active, Premier achat s'affiche en Année, Trimestre, Mois. Utilisez la colonne elle-même (et non sa hiérarchie) dans la matrice.

• D'après la vidéo Build a Cohort Analysis Dashboard in Power BI (Goodly), adaptée et complétée en français.